Hi all!
Now i have a CNR4 and i need program install for CR1000. Everybody help me! thank all...
There is excellent wiring documentation and an example CR1000 program in the CSI CNR4 manual. You can download it from here:
http://www.campbellsci.com/documents/manuals/cnr4.pdf
* Last updated by: IslandMan on 12/2/2010 @ 3:50 AM *
Thank IslandMan!
i had this program but when i downloading to Logger it doing not good. it don't have Card out and two sensor is "NAN" are you have idea?
thanks so much!
* Last updated by: trunghiepsy on 12/2/2010 @ 7:44 PM *
1. Do you have the sensor connected per the manual?
2. Is it the only sensor connected?
3. Paste your program here and I'll have a look.
Yes i have only CNR4 sensor. are you have email or skype?
This is program from of Campbell:
'======================================================================================
' Program Name :OR10000516.CR1
' Date : 03/06/2010
' Author : Owen Davis, CSA
'CR1000 Series Datalogger
'======================================================================================
'Wiring Diagram
'1H CNR4 Pyranometer Up Signal (red)
'1L CNR4 Pyranometer Up Reference (blue)
'ag CNR4 Radiometer Shield (clear)
'2H CNR4 Pyranometer Down Signal (white)
'2L CNR4 Pyranometer Down Reference (black)
'ag
'3H CNR4 Pyrgeometer Up Signal (grey)
'3L CNR4 Pyrgeometer Up Reference (yellow)
'ag
'4H CNR4 Pyrgeometer Down Signal (brown)
'4L CNR4 Pyrgeometer Down Reference (green)
'ag
'5H CNR4 Thermistor Signal (White) and 1 kohm resistor from VX3
'5L
'ag CNR4 thermistor signal reference (thin black)
'VX1 1kohm precision resistor wired to 5H for CNR4 thermistor
'ag CNR4 Thermistor Shield (clear/thick black)
'====================================================================
'Declare Public Variables
Public PTemp, batt_volt
'No delay energy balance sensor.
'NR 01/CNR 4 Net radiometer.
Public Rs_downwell
Public Rs_upwell
Public Rl_downwell
Public Rl_upwell
Public Rn
Public T_nr
Public Rn_flux
Public Rl_downwell_flux
Public Rl_upwell_flux
Public Rs_downwell_flux
Public Rs_upwell_flux
Units PTemp = degC
Units batt_volt = volts
Units Rs_downwell = W/m^2
Units Rs_upwell = W/m^2
Units Rl_downwell = W/m^2
Units Rl_upwell = W/m^2
Units Rn = W/m^2
Units Rl_downwell_flux = MJ/m^2h
Units Rl_upwell_flux = MJ/m^2h
Units Rn_flux = MJ/m^2h
Units Rs_downwell_flux = MJ/m^2h
Units Rs_upwell_flux = MJ/m^2h
'Thermistor resistance variables======================================
Dim Vs_Vx
Dim Rs
Dim Rl_down_meas
Dim Rl_up_meas
'Declare Constants====================================================
'Net radiometer calibration constants
' change this to appropriate sensitivity in calibration sheet
Const sw_down_sensitivity = 14.05
Const sw_Up_sensitivity = 13.46
Const Lw_Down_sensitivity = 7.72
Const Lw_UP_Sensitivity = 7.32
' Scan interval
Const t = 1
Dim NR_SHORT_DW_CAL = 1000/ sw_down_sensitivity 'Unique NR 01/CNR 4 shortwave downwelling multiplier (1000/sensitivity).
Dim NR_SHORT_UW_CAL = 1000/ sw_Up_sensitivity 'Unique NR 01/CNR 4 shortwave upwelling multiplier (1000/sensitivity).
Dim NR_LONG_DW_CAL = 1000/Lw_Down_sensitivity 'Unique NR 01/CNR 4 longwave downwelling multiplier (1000//sensitivity).
Dim NR_LONG_UW_CAL = 1000/Lw_UP_Sensitivity 'Unique NR 01/CNR 4 longwave upwelling multiplier (1000//sensitivity).
'Define Data Tables===================================================
DataTable (daily,True,-1)
DataInterval (0,1,Day,10)
Minimum (1,batt_volt,FP2,False,False)
Minimum (1,PTemp,FP2,False,False) 'Logger Temperature
Maximum (1,PTemp,FP2,False,False)
EndTable
DataTable (Hourly,1,-1)
DataInterval (0,1,Hr,10)
Totalize (1,Rn_flux,IEEE4,False)
Totalize (1,Rl_downwell_flux,IEEE4,False)
Totalize (1,Rl_upwell_flux,IEEE4,False)
Totalize (1,Rs_downwell_flux,IEEE4,False)
Totalize (1,Rs_upwell_flux,IEEE4,False)
EndTable
DataTable (Min,1,-1)
DataInterval (0,1,Min,10)
Average (1,Rn,IEEE4,False)
Average (1,Rs_downwell,IEEE4,False)
Average (1,Rs_upwell,IEEE4,False)
Average (1,Rl_downwell,IEEE4,False)
Average (1,Rl_upwell,IEEE4,False)
EndTable
'Main Program=======================================================
BeginProg
Scan (t,Sec,0,0)
'Measure Logger Temperature and Battery voltage=================
PanelTemp (PTemp,250)
Battery (batt_volt)
'Measure the NR 01/CNR 4 net radiometer=========================
VoltDiff (Rs_downwell,1,mV25,3,TRUE,450,250,NR_SHORT_DW_CAL,0)
VoltDiff (Rs_upwell,1,mV25,4,TRUE,450,250,NR_SHORT_UW_CAL,0)
VoltDiff (Rl_down_meas,1,mV25,7,TRUE,450,250,NR_LONG_DW_CAL,0)
VoltDiff (Rl_up_meas,1,mV25,8,TRUE,450,250,NR_LONG_UW_CAL,0)
'CNR4 thermistor measurement====================================
BrHalf (Vs_Vx,1,mv5000,9,Vx1,1,2500,False,0,250,1.0,0)
Rs = 1000*(Vs_Vx/(1-Vs_Vx))
T_nr = 1/(1.0295e-3+2.391e-4*LN(Rs)+1.568e-7*(LN(Rs))^3)-273.15
'Compute net radiation,downwelling and upwelling longwave radiation.
Rn = Rs_downwell-Rs_upwell+Rl_down_meas-Rl_up_meas
Rl_downwell = Rl_down_meas+(5.67e-8*T_nr*T_nr*T_nr*T_nr)
Rl_upwell = Rl_up_meas+(5.67e-8*T_nr*T_nr*T_nr*T_nr)
'Compute total Solar Flux
Rn_flux = Rn * 0.000001 * t
Rl_downwell_flux = Rl_downwell * 0.000001 * t
Rl_upwell_flux = Rl_upwell * 0.000001 * t
Rs_downwell_flux = Rs_downwell * 0.000001 * t
Rs_upwell_flux = Rs_upwell * 0.000001 * t
'Call Data tables================================================
CallTable Hourly
CallTable Min
CallTable daily
NextScan
EndProg
'====================================================================
Can you fix it have me? thanks IslandMan so much! i will waiting from you!
In the CSI Manual wiring page, 16, there is a notation to add a user supplied jumper wire from the blue to gnd, black to gnd, yellow to gnd and green to gnd. It is not mentioned in the program wiring shown here. Have you done this?
Have you modified the Constants in your program to match the data sheet for the sensor?
What specifically is giving you NAN? In the output tables or the real time measurements?
If you have a program from Campbell why aren't you asking them for support? I'm assuming Owen Davis is from Campbell Scientific Australia?
thanks IslandMan:
This is origin program from Campbell Australia send to me, i did install this program to Logger, 2 sensor is NAN when i collect by in table Onemin of LoggerNet 4.0
about the program in CSI Manual wiring page 16: i can not install to Logger, it warning don't have Card out....and i don't understand jumper wire from the blue to gnd, black to gnd, yellow to gnd and green to gnd. are you give me admonition?
if you want i can send to you some data by email?
best regard: Trung
If you have a cardout instruction, but no card module present you will get a warning but the program will still run OK.
The wire links are simply ways of connecting the negative connection of the sensor both to the L (low input) on the logger and also to the ground connection of the logger. This is done to ensure the sensor output stays within the common mode range of the logger, or put more simply that neither the H or L inputs are pulled outside +/-5 V of the datalogger ground.
The sensor itself is only capable of outputting about 25 mV but static electricity or leakage from other sensors can drag the sensor away from ground, due to the high impedance of the datalogger inputs.
All you need is a short length of single core wire that on one end you put in the same terminal as the L connection and put the other end into an adjacent ground terminal.
One other thing to check is that you have installed the 1k precision resistor between Vx1 and 5H. If you have not fitted this the net radiometer body temperature will be incorrect and then both the upward and downward long wave readings will no doubt read NaN.
Thanks APS!
but i don't know why in program Campbell send to me 5H to VX3 by resistor 1Kohm and 5H to VX1 by resistor 1Kohm
like this 5H will have 3 wire(from white of cable T , 1kohm from VX3 , 1kohm from VX1) i have suspicion this is problem...
can you help me fix it. thank alot
The program is written for the resistor to be connected between 5H and VX1 - see the parameters of the BrHalf instruction. Not sure why the other comment is there, you do not need two resistors. I guess the program was modified from a standard one and the original comment was left in by mistake.
Thanks APS so much! this is original program from Campbell send to me support for CNR4 sensor. Follow you,which i should instal program?
Hi trunghiepsy,
Gavin here from Campbell Scientific in Australia, my apologies there do seem to be inconsistencies in the wiring for your program. Please email info@campbellsci.com.au so we can converse over email from here. We will modify the program and / or wiring comments as needed.
Regards
Gavin Shaw
Thanks Gavin Shaw! i will send to you email! you help me please!
Regards:
Trung